buildscript {
    repositories {
		maven { url = uri("${rootDir}/deps") }
        maven { url = 'https://files.minecraftforge.net/maven' }
        maven { url = 'https://repo.spongepowered.org/repository/maven-public/' }
        maven { url "https://plugins.gradle.org/m2/" }
        gradlePluginPortal()
        mavenCentral()
        jcenter()
    }
    dependencies {
       classpath group: 'net.minecraftforge.gradle', name: 'ForgeGradle', version: '5.1.+', changing: true
		classpath 'gradle.plugin.com.matthewprenger:CurseGradle:1.4.0'
		classpath 'com.modrinth.minotaur:com.modrinth.minotaur.gradle.plugin:2.1.2'
        classpath group: 'org.spongepowered', name: 'mixingradle', version: '0.7-SNAPSHOT'
    }
}

apply plugin: 'net.minecraftforge.gradle'
apply plugin: 'eclipse'
apply plugin: 'idea'
apply plugin: 'maven-publish'
apply plugin: 'org.spongepowered.mixin'
apply plugin: "com.modrinth.minotaur"
apply plugin: "com.matthewprenger.cursegradle"

mixin {
    add sourceSets.main, "nochatrestrictions.refmap.json"
}

version = project.modVersion
group = 'com.aizistral.nochatrestrictions'
archivesBaseName = 'NoChatRestrictions'

// Mojang ships Java 16 to end users in 1.17+ instead of Java 8 in 1.16 or lower, so your mod should target Java 16.
java.toolchain.languageVersion = JavaLanguageVersion.of(16)

println('Java: ' + System.getProperty('java.version') + ' JVM: ' + System.getProperty('java.vm.version') + '(' + System.getProperty('java.vendor') + ') Arch: ' + System.getProperty('os.arch'))

minecraft {
     mappings channel: 'official', version: '1.17.1'
    // makeObfSourceJar = false // an Srg named sources jar is made by default. uncomment this to disable.
    // accessTransformer = file('src/main/resources/META-INF/accesstransformer.cfg')

    runs {
        client {
            workingDirectory project.file('run')
            property 'forge.logging.markers', 'SCAN,REGISTRIES,REGISTRYDUMP'
            property 'forge.logging.console.level', 'debug'
			arg "-mixin.config=nochatrestrictions.mixins.json"

            mods {
                nochatrestrictions {
                    source sourceSets.main
                }
            }
        }

        server {
            workingDirectory project.file('run')
            property 'forge.logging.markers', 'SCAN,REGISTRIES,REGISTRYDUMP'
            property 'forge.logging.console.level', 'debug'
			arg "-mixin.config=nochatrestrictions.mixins.json"

            mods {
                nochatrestrictions {
                    source sourceSets.main
                }
            }
        }
    }
}

repositories {
	maven {  url = "https://repo.spongepowered.org/maven" }
    mavenCentral()
	jcenter()
}

dependencies {
    minecraft 'net.minecraftforge:forge:1.17.1-37.1.1'
    annotationProcessor 'org.spongepowered:mixin:0.8.4:processor'
    annotationProcessor 'com.google.code.gson:gson:2.8.0'
    annotationProcessor 'com.google.guava:guava:21.0'
    annotationProcessor 'org.ow2.asm:asm-tree:7.2'
    annotationProcessor 'org.ow2.asm:asm-commons:7.2'
    annotationProcessor 'org.ow2.asm:asm-util:7.2'
}

jar {
    manifest {
        attributes([
            "Specification-Title": "NoChatRestrictions",
            "Specification-Vendor": "Aizistral",
            "Specification-Version": project.manifestVersion,
            "Implementation-Title": project.name,
            "Implementation-Version": project.manifestVersion,
            "Implementation-Vendor" :"NoChatRestrictions",
            "Implementation-Timestamp": new Date().format("yyyy-MM-dd'T'HH:mm:ssZ"),
			"TweakClass": "org.spongepowered.asm.launch.MixinTweaker",
            "TweakOrder": 0,
            "MixinConfigs" : "nochatrestrictions.mixins.json"
        ])
    }
}

jar.finalizedBy('reobfJar')

curseforge {

    project {
        apiKey = findProperty('curseKey') ?: '0'
        
		id = '1442925'
        releaseType = 'release'
        changelogType = 'markdown'
        changelog = file('../CHANGELOG.md')
		
		addGameVersion '1.17.1'
		addGameVersion '1.17'
		addGameVersion 'Forge'
		addGameVersion 'Java 8'
    }
}

modrinth {
    token = findProperty('modrinthKey') ?: '0'
    projectId = "z440MEwJ"
    versionNumber = project.version
	versionName = "No Chat Restrictions " + project.version
    versionType = "release"
	changelog = rootProject.file("../CHANGELOG.md").text
    uploadFile = jar
    gameVersions = [ '1.17.1', '1.17' ]
	loaders = [ 'forge' ]
}

task upload {
	dependsOn('modrinth')
	dependsOn('curseforge')
}